Const ssfCONTROLS = 3  

sConnectionName = "本地连接"  '可改成需要控制的连接名称，如"无线网络连接"等  

sEnableVerb = "启用(&A)"  
sDisableVerb = "禁用(&B)"   'XP系统中应为 "停用(&B)"  

set shellApp = createobject("shell.application")  
set oControlPanel = shellApp.Namespace(ssfCONTROLS)  

set oNetConnections = nothing  
for each folderitem in oControlPanel.items  
 if folderitem.name  = "网络连接" then  
   set oNetConnections = folderitem.getfolder: exit for  
 end if  
next  

if oNetConnections is nothing then  
 msgbox "未找到网络连接文件夹"  
 wscript.quit  
end if  

set oLanConnection = nothing  
for each folderitem in oNetConnections.items  
 if lcase(folderitem.name)  = lcase(sConnectionName) then  
   set oLanConnection = folderitem: exit for  
 end if  
next  

if oLanConnection is nothing then  
 msgbox "未找到 '" & sConnectionName & "' item"  
 wscript.quit  
end if  

bEnabled = true  
set oEnableVerb = nothing  
set oDisableVerb = nothing  
s = "Verbs: " & vbcrlf  
for each verb in oLanConnection.verbs  
 s = s & vbcrlf & verb.name  
 if verb.name = sEnableVerb then   
   set oEnableVerb = verb    
   bEnabled = false  
 end if  
 if verb.name = sDisableVerb then   
   set oDisableVerb = verb    
 end if  
next  

'debugging displays left just in case...  
'  
'msgbox s ': wscript.quit  
'msgbox "Enabled: " & bEnabled ': wscript.quit  

'not sure why, but invokeverb always seemed to work   
'for enable but not disable.    
'  
'saving a reference to the appropriate verb object   
'and calling the DoIt method always seems to work.  
'  
if bEnabled then  
'  oLanConnection.invokeverb sDisableVerb  
 oDisableVerb.DoIt  
else  
'  oLanConnection.invokeverb sEnableVerb  
 oEnableVerb.DoIt  
end if  

'adjust the sleep duration below as needed...  
'  
'if you let the oLanConnection go out of scope  
'and be destroyed too soon, the action of the verb  
'may not take...  
'  
wscript.sleep 400 

右键发送(sendto)，创建快捷方式到自定义的位置 的vbs
在SendTo文件夹里加上一文件夹的快捷方式后，在右键发送到这个文件夹的是这些文件的一个副本，实际上是一个复制的过程，有时候我们只希望是快捷

WINDOWS脚本实践:为SAP补丁制作的VBS脚本代码
脚本主要功能包括：注册表读取与修改文件内容修改如HOSTS、SERVICES文件文件属性修改和文件复制系统环境变量设置等，仅供参考'SAP设置脚本'编写:SCZ2005

Adsutil.vbs 在脚本攻击中的妙用[我非我原创]
一、简单介绍adsutil.vbs是什么？相信用过IIS的网管员不会不知道。这是IIS自带的提供于命令行下管理IIS的一个脚本。位于%SystemDrive%InetpubAdminScripts目录